Codificação de veículos ferroviários no Brasil
Rotina em Basic
para calcular o dígito-verificador

Eliezer Magliano — Centro-Oeste n° 80 — 1°-jul-1993

Este programa calcula, apresenta na tela, e grava em disco o dígito verificador de vagões de carga da Rede Ferroviária Federal S/A, bastando que o modelista forneça os 6 dígitos que compõem sua numeração oficial. Caso seja fornecido um número com menos de 6 dígitos, o programa pede que seja feita a correção antes de prosseguir.

Ao iniciar o trabalho, a primeira providência do programa é perguntar se já existe arquivo com os números de outros vagões, calculados anteriormente. Caso você diga que não existe, ele iniciará a gravação de um novo arquivo, eliminando o arquivo anterior, se já existe. Se você disser que sim, ele usará o arquivo já existente.

Para sair, digite "f" ou "F" de fim.

Primeiro, o programa precisa ser compilado. Digite-o e grave-o com o nome de NumTrem.ASC, compilando em seguida. Se você tiver um antiquíssimo livro de Basic, consulte-o. O Basic não mudou quase nada.

No IBM-PC, rode GwBasic; e em seguida digite Run "C:\Diretorio\NumTrem" (Enter ou Return), onde o Diretorio é opcional, caso não seja o diretório corrente.

Dentro do GwBasic, use (Files) para listar os arquivos do diretório corrente; (Load) para carregar o programa sem rodá-lo; (List) para listá-lo; (Save) para salvar as alterações, se houver; (Ctrl-C) ou (Ctrl-Break) para parar.

A numeração dos vagões da RFFSA foi apresentada no CO-72, juntamente com um programa semelhante, em dBase. A numeração das locomotivas e todos os demais veículos da RFFSA, foi apresentada por João Bosco Setti no CO-78.

10 CLS:KEY OFF

20 INPUT"Arquivo de dados `checados' ja existe no disco (S/N)";AR$

30 IF AR$="S" OR AR$="s" THEN 50

40 OPEN"checados.dat" FOR OUTPUT AS #1:CLOSE

50 OPEN"checados.dat" FOR APPEND AS #2

60 CLS:LI=2

70 LOCATE 10,20:INPUT"Numero";NU$

80 LOCATE 20,40:PRINT"                 "

90 IF LEN(NU$)<6 THEN LOCATE 20,40:PRINT"Complete o Numero":GOTO 70

100 IF LEN(NU$)>6 THEN LOCATE 20,40:PRINT"Seis digitos !":LOCATE 10,25:PRINT"          ":GOTO 70

110  N1= 7*VAL(MID$(NU$,1,1))

120  N2= 6*VAL(MID$(NU$,2,1))

130  N3= 5*VAL(MID$(NU$,3,1))

140  N4= 4*VAL(MID$(NU$,4,1))

150  N5= 3*VAL(MID$(NU$,5,1))

160  N6= 2*VAL(MID$(NU$,6,1))

170 CH=11-INT((N1+N2+N3+N4+N5+N6) MOD 11)

180 IF CH=10 THEN RE$=NU$+"-0":GOTO 200

190 IF CH=11 THEN RE$=NU$+"-1":GOTO 200 ELSE RE$=NU$+"-"+RIGHT$(STR$(CH),1)

200 LOCATE 15,35:PRINT RE$

210 LOCATE LI,2:PRINT RE$

220 PRINT #2,RE$

230 IF LI<21 THEN LI=LI+1 ELSE LI=2

240 LOCATE 17,40:PRINT CH

250 LOCATE 20,40:PRINT"Tudo ok (F termina)?"

260 OK$=INKEY$:IF OK$="" THEN 260

270 IF OK$="F" OR OK$="f" THEN 280 ELSE LOCATE 10,25:PRINT"                      ":LOCATE 20,40:PRINT"                      ":GOTO 70

280 CLOSE:CLS:END

Busca no site